MacFormat 1999 Spring/macformat-077.iso/Shareware Plus/Development/Akua Sweets 131/Akua Sweets Examples/Network/Batch Copy/PowerBatch V1.2

Text File | 1999-03-04 | 16.4 KB | 632 lines | [TEXT/ToyS]

-- User setable properties
property kasAllowAlerts : true -- Set to false to stop any alerts from appearing
property kasServerAlerts : true -- Set to false to stop warnings about missed servers
property kasBatchCopyList : ":Batch Copy List" -- The list of files that we should copy
property kasBatchDest : "::" -- The destination of the copies
property kasOverwrite : false -- Overwrite existing?
property kasResume : true -- Resume partial copies?
property kasJustDoIt : false -- Disconnect wrong ARA connections without asking?

-- Internal/User setable globals
property kasTest : false -- Just testing the script?

-- Internal/User setable globals
property gasLinkSet : false -- Has the friend been asked for? - set to true to never ask
property gasLinkNeed : false
property kasLinkUserDft : "CasaVision" -- Defaults for linking access
property kasLinkPassDft : ""

property gasServSet : false
property gasServNeed : false
property kasServUserDft : "Synapse" -- Defaults for server access
property kasServPassDft : ""
property kasServNTDft : ""

-- Internal globals
global gasLinkUser -- Our friend on all machines
global gasLinkPass -- Our friend's password on all machines
global gasServUser -- Our friend on all machines
global gasServPass -- Our friend's password on all machines
global gasServNT -- Volume password

-- Internal globals
property kasBatchType : "RemoteBatch"
property gasOurAlias : "" -- The alias we own
property gasOurStatus : "" -- Empty, "RemoteLauncher" or "RemoteFolder"
property gasOurServer : "" -- Set to server of gasOurAlias
property gasOurZone : "" -- Set to zone of gasOurAlias
property gasOurName : "" -- Name of original alias
property gasOurVol : "" -- Name of volume alias resides on
property gasOurType : "" -- If we are a RemoteLauncher, this is our file type
property gasCopyLoc : {0, 0} -- The location of the copy window

-- Remote access stuff
property kraConnected : "connected" -- ARA osax strings
property kraProtocol : "ARAP"
property gasRemote : false -- set internally to true if volume was a RemoteAccess volume
property gasRemoteCfg : "" -- Set internally to ARA config needed for this access
property gasRemoteServer : "" -- Set internally to check if we are already connected to the correct server
property gasRemoteAlias : false --Set internally to rebuild ARA with alias instead of osax
property gasRemoteNum : "" -- Set internally to the telephone number of the remote machine
property gasRemoteUsr : "" -- Set internally to the login user for the remote machine


on run
    if (kasTest) then
        set gasOurAlias to ((item 1 of (list disks)) & ":") as alias
        RunRemoteBatch()
    else
        if (gasOurStatus is "") then
            ShowInitAlert()
        else if (gasOurStatus is kasBatchType) then
            RunRemoteBatch()
        else
            beep
        end if
    end if
end run


on open fsObjs
    if (gasOurStatus is "") then
        if the number of items in fsObjs is not 1 then
            ShowInitAlert()
        else
            SetScriptAlias(item 1 of fsObjs)
        end if
    else if (gasOurStatus is kasBatchType) then
        set wasMounted to IsVolMounted(gasOurVol)
        if (RunRemoteBatch()) then
            repeat with fsObj in fsObjs
                try
                    set gasCopyLoc to ¬
                        (AkuaCopy fsObj located at gasCopyLoc with resuming given «class Dest»:gasOurAlias)
                on error err
                    ShowAlert("An error (" & (err as string) & ") occured copying “" & (fsObj as string) & "”. The network may have been interrupted or a disk error may have occured")
                end try
            end repeat
            if (not wasMounted) then ¬
                PutAwayVol(gasOurVol)
        end if
    end if
end open


on RunRemoteBatch()
    -- Get the user/password
    GetFriend(false)

    if (not gasServSet) then return

    set mounted to false

    -- Mount the remote volume
    if (not gasRemote or not gasRemoteAlias) then
        try
            «event ÅkuNMSVm» gasOurVol ¬
                given «class MSrv»:gasOurServer ¬
                , «class TZon»:gasOurZone ¬
                , «class USER»:gasServUser ¬
                , «class PASS»:gasServPass ¬
                , «class VPwd»:gasServNT
            set mounted to true
        on error
            if (CouldBeSharing(gasOurZone, gasOurServer)) then
                try
                    «event ÅkuNMSVm» gasOurVol ¬
                        given «class MSrv»:gasOurServer ¬
                        , «class TZon»:gasOurZone ¬
                        , «class USER»:gasServUser ¬
                        , «class PASS»:gasServPass ¬
                        , «class VPwd»:gasServNT
                on error
                    if (kasServerAlerts) then
                        ShowMountAlert()
                    else
                        beep
                    end if
                    set mounted to false
                end try
            else
                if (kasServerAlerts) then
                    ShowMountAlert()
                else
                    beep
                end if
                set mounted to false
            end if
        end try
    end if

    if (mounted) then
        try
            -- Mount the remote volume
            set sourceFolder to resolve server alias gasOurAlias ¬
                as user name gasServUser with password gasServPass ¬
                with volume password gasServNT
            set mounted to true
        on error
            set mounted to false
            if (kasServerAlerts) then
                if (gasRemote) then
                    ShowRemoteAlert()
                else
                    ShowMountAlert()
                end if
            else
                beep
            end if
        end try

        if (mounted) then
            -- Our destination folder
            set destFolder to PathToAlias(kasBatchDest)

            -- Read in our list
            set myBatchList to PathToAlias(kasBatchCopyList)
            set myBatchText to read data from the data fork of myBatchList

            -- Kill comments
            set myBatchText to (collect lines of myBatchText that match "&#:*")
            RunRemoteCopy(sourceFolder, destFolder, myBatchText)
        end if
    end if

    return mounted
end RunRemoteBatch


property kasPgLoc : {0, 0}

on RunRemoteCopy(src, dst, itemList)
    set srcItems to list folder src
    set srcPath to src as string

    set pg to display progress titled ¬
        "Batch Copy" subtitled ("Total Items: " & the number of items of srcItems) ¬
        located at kasPgLoc

    repeat with x in srcItems
        display progress pg labeled x

        if (the kind of entry in src named x) is a folder then
            RunRemoteCopy((srcPath & x) as alias, dst, itemList)
        else if (collect lines of itemList that match x) is not "" then
            try
                set gasCopyLoc to ¬
                    (AkuaCopy ((srcPath & x) as alias) resuming kasResume located at gasCopyLoc given «class Dest»:dst, «class Over»:kasOverwrite)
            on error
                beep
            end try
        end if
    end repeat

    set pgLoc to screen location of (display progress pg with disposal)
    if (pgLoc is not kasPgLoc) then set kasPgLoc to pgLoc
end RunRemoteCopy


on SetScriptAlias(aliasObj)
    -- My Path
    set myPath to (path to me)

    -- Grab an alias
    set gasOurAlias to aliasObj
    set aInfo to alias info from gasOurAlias
    set fInfo to basic info for gasOurAlias
    set xInfo to extended info for myPath

    -- Save the info we need
    set gasOurServer to alias server of aInfo
    set gasOurZone to alias zone of aInfo
    set gasOurVol to alias volume of aInfo
    set gasOurName to original name of aInfo
    set gasOurType to system type of fInfo

    -- Set our parent's name to dropped name
    set newName to "Batch " & (catalog name of fInfo)
    if (length of newName > 30) then ¬
        set newName to the text from character 1 ¬
            to (30 - (length of newName)) of newName
    try
        collate (parent spec of xInfo) renaming it to newName
    on error
        beep
    end try

    -- What will we be
    set gasServNeed to true
    set gasWasRemote to IsRemoteAccessed()
    set gasOurStatus to kasBatchType

    -- Get the user/password
    GetFriend(false)

    -- Check ARA connection
    set gasRemote to IsRemoteAccessed()
    if (gasRemote) then WantRemoteAccess()

    -- Set our icon to dropped icon
    set myPath to (path to me)
    set ourIcon to (the icon for gasOurAlias)
    set the icon of myPath to ourIcon

    try
        tell application "Finder" to update myPath -- Double dose?
    on error
        beep
    end try
end SetScriptAlias


on GetFriend(override)
    -- Build ARA connection?
    if (gasRemote and not gasRemoteAlias) then ¬
        if not BuildRemoteAccess() then ¬
            return

    -- Get linking (and server) user?
    if (gasLinkNeed) then
        GetOneFriend(true, override)
        if (gasRemote and gasRemoteAlias) then ¬
            GetOneFriend(false, override)
    end if

    -- Get server user?
    if (gasServNeed) then GetOneFriend(false, override)
end GetFriend


on GetOneFriend(isLink, override)
    if (isLink) then
        set userMode to "linking"
        if (gasLinkSet) then
            set defUser to gasLinkUser
            set defPass to gasLinkPass
        else
            set defUser to kasLinkUserDft
            set defPass to kasLinkPassDft
        end if
        set defNT to kasServNTDft
        set passButtons to {"Cancel", "OK"}
        set passButton to 2
    else
        set userMode to "sharing"
        if (gasServSet) then
            set defUser to gasServUser
            set defPass to gasServPass
            set defNT to gasServNT
        else
            set defUser to kasServUserDft
            set defPass to kasServPassDft
            set defNT to kasServNTDft
        end if
        set passButtons to {"Cancel", "NT Password…", "OK"}
        set passButton to 3
    end if

    set usrPwd to KeyChainLookUp(gasOurZone, gasOurServer, isLink)

    if (override or usrPwd is {}) then
        set chosen to display dialog ¬
            "Enter the friendly " & userMode & ¬
            " user's name for the server \"" & gasOurServer ¬
            & "\"…" default answer defUser ¬
            default button 2 with icon note

        if (the button returned of chosen is "OK") then
            set defUser to the text returned of chosen
        else
            return
        end if

        set chosen to display dialog ¬
            "Enter the friendly " & userMode & ¬
            " user's password…" buttons passButtons ¬
            default answer defPass default button passButton with icon note

        if (the button returned of chosen is not "Cancel") then
            set defPass to the text returned of chosen
        else
            return
        end if

        if (the button returned of chosen is "NT Password…") then
            set chosen to display dialog ¬
                "Enter the volume password for Windoze NT…" default answer ¬
                defNT default button 2 with icon note

            if (the button returned of chosen is not "Cancel") then
                set gasServNT to the text returned of chosen
            else
                return
            end if
        end if

        -- Save encrypted user/pass for future access
        KeyChainSave(gasOurZone, gasOurServer, isLink, defUser, defPass, "")
    else
        set defUser to item 1 of usrPwd
        set defPass to item 2 of usrPwd
        set defNT to item 3 of usrPwd
    end if

    if (isLink) then
        set gasLinkSet to true
        set gasLinkUser to defUser
        set gasLinkPass to defPass
    else
        set gasServSet to true
        set gasServUser to defUser
        set gasServPass to defPass
        set gasServNT to defNT
    end if
end GetOneFriend


on PathToAlias(pathStr)
    if (character 1 of pathStr is ":") then
        set daddy to parent spec of (extended info for (path to me))
        set daddyStr to the text from character 1 to -2 of (daddy as string)
        set pathStr to daddyStr & pathStr
    end if

    return pathStr as alias
end PathToAlias


on PutAwayVol(volName)
    -- Volume
    try
        set vAlias to (vol alias of (the volume info of volume named volName))
        tell application "Finder"
            update vAlias
            pause for 2 with seconds timing -- Give some time to the Finder?
            put away item vAlias
        end tell
    on error
        beep
    end try
end PutAwayVol


on IsVolMounted(volName)
    -- Volume
    try
        set x to (volName & ":") as alias
        return true
    on error
        return false
    end try
end IsVolMounted


property sasShareLoc : {0, 0}

on CouldBeSharing(servZone, servName)
    GetOneFriend(true, false) -- Get linking user

    talk as user gasLinkUser ¬
        with password gasLinkPass ¬
        on server servName ¬
        in AppleTalk zone servZone

    try
        set isOn to («class fshr» ¬
            of application kasFinder ¬
            of machine servName ¬
            of zone servZone)

        if (not isOn) then
            set «class fshr» of application kasFinder ¬
                of machine servName ¬
                of zone servZone to true

            set inf to (display info titled ¬
                "Wait for Sharing" message ¬
                (servZone & ":" & servName) ¬
                    located at sasShareLoc)

            set waitSecs to 333

            repeat while not («class fshr» of application kasFinder ¬
                of machine servName ¬
                of zone servZone)
                display info inf message ¬
                    ("Wait another " & waitSecs & " seconds") at line 2
                pause for 2 with seconds timing
                set waitSecs to waitSecs - 2
                if (waitSecs < 1) then exit repeat
            end repeat

            if («class fshr» of application kasFinder ¬
                of machine servName ¬
                of zone servZone) then
                display info inf message ¬
                    "It is up!" at line 2
            else
                display info inf message ¬
                    "Can't get it up!" at line 2
                beep
            end if

            set sasShareLoc to screen location of ¬
                (display info inf with disposal)

            return («class fshr» of application ¬
                kasFinder of machine servName of zone servZone)
        end if
    on error errStr
        if (errStr contains "-911") then
            GetOneFriend(true, true)
            return CouldBeSharing()
        end if
    end try

    return false
end CouldBeSharing


on ShowAccessAlert()
    ShowServerAlert("The remote access connection for the item on " & gasOurServer ¬
        & " in zone " & gasOurZone & " failed to be made.")
end ShowAccessAlert


on ShowRemoteAlert()
    ShowServerAlert("Couldn't find remote item on " & gasOurServer ¬
        & " in zone " & gasOurZone & ¬
        " due to ARA connection problems or changes in the remote zone or on the remote volume.")
end ShowRemoteAlert


on ShowMountAlert()
    ShowServerAlert("Couldn't mount volume " & gasOurVol & ¬
        " from " & gasOurServer ¬
        & " in zone " & gasOurZone)
end ShowMountAlert


on ShowConnectAlert(appName)
    ShowServerAlert("Couldn't connect to " & appName & " on " & ¬
        gasOurServer & " in zone " & gasOurZone)
end ShowConnectAlert


on ShowServerAlert(msg)
    set choice to ¬
        display dialog msg buttons {"Reenter Password", "OK"} ¬
            default button 2 with icon stop

    if (button returned of choice is not "OK") then GetFriend(true)
end ShowServerAlert


on ShowInitAlert()
    ShowAlert("This script must first be activated by dropping exactly one item on it." & ¬
        return & return & "Please see the information file that accompanied it.")
end ShowInitAlert


on ShowOpenAlert()
    ShowAlert("This script is currently in Launcher mode and can thus not process any files dropped on it." & ¬
        return & return & "To reconfigure the script, open it with ScriptEditor and save it.")
end ShowOpenAlert


on ShowAlert(msgStr)
    if (kasAllowAlerts) then ¬
        display dialog msgStr buttons {"Damn!"} ¬
            default button 1 with icon stop
end ShowAlert


on ShowChoice(msgStr)
    return (ShowChoices(msgStr, {"No", "Yes"}) is "Yes")
end ShowChoice


on ShowChoices(msgStr, choices)
    set choice to ¬
        display dialog msgStr buttons choices ¬
            default button (number of items of choices) ¬
            with icon stop
    return (button returned of choice)
end ShowChoices


property kasKeyChainPassword : "PowerScript" -- Encrypt stored data with this
property kasPrefsFileName : "PowerScript Prefs" -- File name in <Preferences>

on KeyChainLookUp(zoneName, serverName, isLinking)
    set prefOwner to "πSRV"
    if (isLinking) then set prefOwner to "πLNK"

    try
        set myKeyData to load preference named (zoneName & ":" & serverName) ¬
            of type prefOwner in file named kasPrefsFileName
    on error
        return {}
    end try

    return (encrypt the data myKeyData with password kasKeyChainPassword)
end KeyChainLookUp


on KeyChainSave(zoneName, serverName, isLinking, usr, pwd, ntPwd)
    set myKey to encrypt the data {usr, pwd, ntPwd} with password kasKeyChainPassword

    set prefOwner to "πSRV"
    if (isLinking) then set prefOwner to "πLNK"

    save preference myKey named (zoneName & ":" & serverName) ¬
        of type prefOwner ¬
        in file named kasPrefsFileName
end KeyChainSave


on IsRemoteAccessed()
    try
        set araStats to (RA status)
    on error
        return false
    end try

    return ((state of araStats) is kraConnected) ¬
        and ((protocol of araStats) is kraProtocol)
end IsRemoteAccessed


on WantRemoteAccess()
    set gasRemoteAlias to true

    if kasJustDoIt or ¬
        (ShowChoice("PowerScript noticed that an ARA connection is active." & return & return & ¬
            "Do you wish the connection to be built before searching for the item?" & return & return & ¬
            "(If you answer No, the ARA connection may be made by resolving the alias.)")) then

        -- Get the ARA config for the alias
        set configs to RA configurations whose numbers are gasRemoteNum ¬
            whose users are gasRemoteUsr

        if (the number of items in configs) > 0 then
            set gasRemoteCfg to item 1 of (item 1 of configs) -- The name of the config to use
            set gasRemoteServer to server name of (RA status)
            set gasRemoteAlias to false
        end if
    end if
end WantRemoteAccess


on BuildRemoteAccess()
    set araIsOn to IsRemoteAccessed()

    if (araIsOn) then
        -- Connected to correct server?
        if (server name of (RA status)) is gasRemoteServer then
            return true
        else
            RA disconnect
            set araIsOn to IsRemoteAccessed()
        end if
    end if

    if (not araIsOn) then
        -- Save current config, set it to ours, connect, set it back
        set saveConfig to RA configuration gasRemoteCfg

        try
            RA connect
        on error
            beep
        end try

        RA configuration saveConfig

        if (IsRemoteAccessed()) then return true
    end if

    ShowAccessAlert()
    return false
end BuildRemoteAccess